home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Games Galore!
/
Shareware Games Galore!.iso
/
arcade
/
pcgolf
/
aintro.asc
< prev
next >
Wrap
Text File
|
1984-02-18
|
3KB
|
79 lines
10000 '*************************************************************
10010 '***** PC-GOLF THE GOLFER's PROGRAM PC-GOLF *****
10020 '***** Version 1.3 (C) 1982,1983,1984 Ed Chandler *****
10030 '*************************************************************
10040 '+ + + + + + + + + + + + + + + + + + + + + + + + + + + + + + +
10050 ' 1. INTRODUCTION
10060 '+ + + + + + + + + + + + + + + + + + + + + + + + + + + + + + +
10070 '
10080 EXT$=".TXT"
10090 AI$(1)=DEV$+CM1$+EXT$:AI$(2)=DEV$+CM2$+EXT$:AI$(3)=DEV$+CM5$+EXT$
10100 AI$(4)=DEV$+CM4$+EXT$:AI$(5)=DEV$+CM3$+EXT$:AI$(6)=DEV$+CM6$+EXT$
10110 '
10120 CLS:PRINT "INTRODUCTION TO PC-GOLF":PRINT
10130 PRINT"While you are using the Introduction the"
10140 PRINT"only active keys on the keyboard are for"
10150 PRINT"getting a new page of information, or"
10160 PRINT"for returning to the menu."
10170 PRINT:PRINT"The page-up and page-down keys, PgUp and PgDn,"
10180 PRINT"will let you see the information you want.":PRINT
10182 PRINT"You can also use the letters 'U' and 'D'"
10184 PRINT"instead of the PgUp and PgDn keys.":PRINT
10190 PRINT"Use the letter M to return to the menu.":PRINT:GOSUB 580
10200 CLS:PRINT "INTRODUCTION TO PC-GOLF":PRINT
10210 PRINT " You can get extra information for"
10220 PRINT"each of the six items in the menu.":PRINT
10230 '
10240 PRINT MNU1$:PRINT SPC(1)MNU2$:PRINT SPC(2)MNU5$
10250 PRINT SPC(3)MNU4$:PRINT SPC(4)MNU3$:PRINT SPC(5)MNU6$
10260 PRINT:PRINT "M. Return to PC-GOLF's menu."
10270 IF ROS=0 THEN 10290
10280 DEF SEG=&H40:I%=PEEK(&H17):I%=I% AND NOT 32:POKE &H17,I% 'numlock off
10290 '
10300 '
10310 PRINT:LOCATE CSRLIN,POS(0),1
10320 M1$="key":M2$="(1,2,3,4,5,6 or M). ":GOSUB 570
10330 IF KB$="M" OR KB$="m" THEN 10650 'free mem?
10340 IF KB<1 OR KB>6 THEN GOSUB 610:GOTO 10200
10350 RESTORE 838:GOSUB 810
10360 X=200 'max # lines in file
10370 A$=AI$(KB)
10380 OPEN A$ FOR INPUT AS #1
10390 FOR I=1 TO X:LINE INPUT #1,A$(I):IF EOF(1) THEN CLOSE:GOTO 10410
10400 NEXT
10410 LAST=I-1:PG=23
10420 '+++++
10430 CLS:LOCATE 25,40:COLOR 0,15,0:PRINT" Introduction - PgUp - PgDn - M ";
10440 COLOR 7,0,0:LOCATE 1,1,0
10450 FOR I=1 TO PG:LOCATE I,1:PRINT A$(I):NEXT:F=I
10460 '+++++
10470 KB$=INKEY$:IF KB$="" THEN 10470
10480 IF KB$="m" OR KB$="M" THEN 10200
10482 IF KB$="U" OR KB$="u" THEN 10600 ' page up
10484 IF KB$="D" OR KB$="d" THEN 10540 ' page down
10490 IF LEN(KB$)<>2 THEN 10470 ELSE KB=ASC(RIGHT$(KB$,1))
10500 '
10510 IF KB=73 THEN 10600
10520 IF KB<>81 THEN 10470
10530 '+++++ page down
10540 IF F>=LAST THEN 10470
10550 L=F+PG-1:IF L>LAST THEN L=LAST
10560 CLS:LOCATE 25,40:COLOR 0,15,0:PRINT" Introduction - PgUp - PgDn - M ";
10570 COLOR 7,0,0:LOCATE 1,1,0
10580 FOR I=F TO L:PRINT A$(I):NEXT:F=I:GOTO 10470
10590 '+++++ page up
10600 IF F=1 OR F=24 THEN 10470
10610 L=F-PG-1:F=L-PG+1:IF L<PG THEN F=1:L=PG
10620 CLS:LOCATE 25,40:COLOR 0,15,0:PRINT" Introduction - PgUp - PgDn - M ";
10630 COLOR 7,0,0:LOCATE 1,1,0
10640 FOR I=F TO L:PRINT A$(I):NEXT:F=I:GOTO 10470
10650 FOR I=1 TO 200:A$(I)="":NEXT I:GOTO 530 'back to main
10660 '++++
14000 '+++++ grunt work
14010 DELETE 490-9999
14020 SAVE"b:intro.asc",A
14030 RUN"b:main.bas"
15000 'for chain delete
+
14000 '+++++ grunt work
14010 DELETE 490-9999